ポモドーロタイマーを作る

ポモドーロタイマーを作りました。

ポモドーロタイマーとは、ポモドーロテクニックによる時間管理術のためのタイマーで、あ〜、詳しいことはググって下さい (^_^;)

ポモドーロタイマーは、Chrome の拡張機能とかスマホのアプリとかで使っていて、それぞれ便利です。が、パソコン使ってないとダメ、とか、スマホの電池がぁ〜、とか、まぁそんなもの。
キッチンタイマーとか使うこともできるわけですが、いちいち設定するのは面倒くさい。なら、てめーの都合の良いように作っちゃえ、ってことで、巣籠り工作気分のガジェットです。

写真が完成品。秋月電子通商にあったプラスチックケースに入れました。基板は毎度のユニバーサル基板、ケースに合わせての C 基板です。裏側に Arduino NANO が付いています。
電源は単 3 電池 4 本。USB からでも給電できます。電池がどのくらいもつかわからないのですが、毎日使って 2~3 週間ぐらいもってくれたら嬉しいかな、と。

7 セグメント LED は部品箱にあったアノードコモン 1 桁のものを 2 個並べました。ケースと基板、タクトスイッチ、ピエゾスピーカーなどは今回購入しましたが、あとは部品箱にあった部品です。

回路図
スケッチ
ユニバーサル基板
NANO の電源 LED を消す
ポモドーロタイマーを使ってみると

回路図

回路図です。

7 セグメント LED をダイナミック点灯させるなど、これまでにやったことのあることばかりですね。強いて言えば、電池駆動とピエゾスピーカーが俺は初めてだけど、難しいことではありません。

電池は Arduino の Vin につなぎます。電圧が 4V ぐらいに下がっても、Arduino の定格外ですが、問題なく動きました。

7 セグメント LED はアノードコモンですので、セグメントをつなぐデジタルピンはシンクで動きます。セグメントの順方向電圧は 1.7V 、電流は 7mA です。
デジット電流は 49mA になりますから、デジタルピンをそのまま使うことはできません。デジット制御は PNP トランジスタ 2SA1015 を使います。ベース電流は 0.9mA です。

タイマーのスタートとストップにタクトスイッチを使っています。割り込み処理も利用できるように、スイッチは D2 、D3 につなぎ、内部プルアップしています。

表示用の LED には 0.9mA 流しています。少ない電流ですが、表示用としては十分な明るさ。もう少し落としたほうが良かったかなと思うくらいです。A3 、A4 ピンにつないでいますが、デジタル出力として使用します。

ピエゾスピーカーも A5 ピンにつないでいますが、デジタル出力として使います。
ピエゾスピーカーを Arduino に直接つないでいる回路を見かけますが、ピエゾスピーカーは指で弾いただけでも 10V 以上を発電しますので、IC など壊してしまいます。データシートに書かれているように 1~2KΩ の抵抗を入れておきましょう。

スケッチ

Arduino NANO のスケッチです。UNO でもいけると思います。

7 セグメント LED の制御に関して「Arduinoで遊ぶページ」を参考にさせていただきました。いつもありがとうございます。

頭から順に、簡単に、備忘録的解説していきます。



/* 
    Pomodoro Timer v.1.5b 2021.02.22 meyon

 */

#include <avr/sleep.h>
#include <TimerOne.h>
#include "pitches.h"

電池駆動しますので使わないときにスリープさせるための avr/sleep.h 、ダイナミック点灯の割込みに使う TimerOne.h 、音を出すためにスケッチ例 toneMelody の pitches.h をインクルードしています。



#define DIGIT_ON LOW
#define DIGIT_OFF HIGH
#define SEGMENT_ON LOW
#define SEGMENT_OFF HIGH
#define BUTTON_ON LOW
#define BUTTON_OFF HIGH
#define LED_ON HIGH
#define LED_OFF LOW

デジタルピンをシンクやソース、あるいはプルアップ、プルダウンで使うとき、HIGH 、LOW で表記するとわけわからなくなるので、それぞれ意味のある表記に定義しています。



const int digitPins[] = {11, 12};
const int segmentPins[] = {4, 5, 6, 7, 8, 9, 10};
const int buttonPins[] = {2, 3};
const int ledPins[] = {17, 18};
const int piezoPin = 19;

const int periodsTable[] = {25, 5, 25, 5, 25, 15}; // {FORCUS, REST, ...}

const int numberOfDigitPins = sizeof(digitPins) / sizeof(digitPins[0]);
const int numberOfSegmentPins = sizeof(segmentPins) / sizeof(segmentPins[0]);
const int numberOfButtonPins = sizeof(buttonPins) / sizeof(buttonPins[0]);
const int numberOfLedPins = sizeof(ledPins) / sizeof(ledPins[0]);
const int numberOfPeriods = sizeof(periodsTable) / sizeof(periodsTable[0]);

const unsigned long unitTime = 60000; // mS
const unsigned long sleepTime = 180000; // mS

使用するピンの定義など。

24 行目の periodsTable[] は集中期間 (FORCUS) 、休憩期間 (REST) の時間テーブルです。25 分集中して 5 分休憩、3 回目の休憩は 15 分です。お好きに設定して下さい。

32 行目の unitTime はタイマーの単位時間 (1 分) 、33 行目の sleepTime はスリープモードまでの時間 (3 分) です。



bool resetTimer = false;
bool isRun = false;
int currPeriod = 0;
volatile int numbersToDisplay = 0;

その他、グローバル変数など。



// Data for displaying numbers
const byte digits[] = {
  0b00111111, // 0
  0b00000110, // 1
  0b01011011, // 2
  0b01001111, // 3
  0b01100110, // 4
  0b01101101, // 5
  0b01111101, // 6
  0b00100111, // 7
  0b01111111, // 8
  0b01101111, // 9
  0b00000000, // blank
};

数字を表示するためのセグメントのデータ。10番目はゼロサプレスのためのブランクデータです。



// Notes in the melody:
// Sample
const int melody[] = {
  NOTE_C4, NOTE_G3, NOTE_G3, NOTE_A3, NOTE_G3, 0, NOTE_B3, NOTE_C4
};
const int noteDurations[] = {
  4, 8, 8, 4, 4, 4, 4, 4
};
const int noteTempo = 1000;
const float notePause = 1.30;
const int numberOfMelody = sizeof(melody) / sizeof(melody[0]);
bool stopNote = false;

期間終了時に鳴らすメロディーデータです。スケッチ例の toneMelody をそのまま利用していますので、pitches.h をコピーしておく必要があります。
お好きなメロディーを設定して下さい。ちなみに俺は「パプリカ」を入れてたりします (^_^;) が、著作権とかややこしいので、データは非公開です。



// Display interrupt
void displayInterrupt() {
  displayNumbers();
}

ダイナミック点灯を割り込み処理で行ないますので、その割り込みハンドラ。
えーと、これは必要？さぁ (^_^;) いいんじゃね？



// Turn off digits display
void turnOffDigits() {
  for (int i = 0; i < numberOfDigitPins; i++) {
    digitalWrite(digitPins[i], DIGIT_OFF);
  }
}

すべてのデジットを消す処理。



// Display number in segments
void displayNumber(int n) {
  for (int i = 0; i < numberOfSegmentPins; i++) {
    digitalWrite(segmentPins[i], digits[n] & (1 << i) ? SEGMENT_ON : SEGMENT_OFF);
  }
}

数字のセグメントデータに応じてセグメントを操作する処理。引数 n を渡すと、digits[n] の各ビットが 1 なら点灯、0 なら消灯させて、その数字を表示します。



// Display numbers in digits
void displayNumbers() {
  static int pos = 0;
  static int num = numbersToDisplay;

  int rem  = num % 10;
  if ((0 < pos) & (0 == rem)) rem = 10;

  turnOffDigits();
  displayNumber(rem);
  digitalWrite(digitPins[pos], DIGIT_ON);

  num /= 10;
  pos++;
  if (numberOfDigitPins <= pos) {
    pos = 0;
    num = numbersToDisplay;
  }
}

複数桁の 7 セグメント LED をダイナミック点灯させる処理。割り込み処理で実行します。

ダイナミック点灯でこれまでやっていたのは、セグメントをセットしてからデジットを点灯、数ミリ秒待って消灯し、次の桁の処理へ行くってやり方です。が、割り込み処理のなかで delay() するのはうまくありません。
そこで、割り込み毎に一桁ずつ点灯させるようにしています。割り込み処理は 1 ミリ秒毎に行ないますので、2 ミリ秒で二桁表示することになります。



// Unit timer
bool unitTimer() {
  static unsigned long prevTime = millis();
  bool timeUp = false;

  if (resetTimer) {
    prevTime = millis();
    resetTimer = false;
  }

  unsigned long currTime = millis();
  if (unitTime <= (currTime - prevTime)) {
    timeUp = true;
    prevTime = millis();
  }
  return timeUp;
}

1 分ごとにタイマーのフラグを出力します。

本来ならこれも割り込み処理したいところですね。でも、複数の割り込み処理はいろいろ不都合もあるらしいので、millis() を利用しています。25 分間での誤差はほとんど問題にならない程度です。



// Detect buttons status and behavior
void detectButtons() {
  static const int START_BUTTON = 0;
  static const int STOP_BUTTON = 1;

  if (BUTTON_ON == digitalRead(buttonPins[START_BUTTON])) isRun = true;
  if (BUTTON_ON == digitalRead(buttonPins[STOP_BUTTON])) isRun = false;
}

ボタン入力の検知です。難しいアクションはやりません。
赤いボタンがスタートで isRun フラグを true にセット、青がストップで isRun フラグを false にします。



// Start the period
void startPeriod(int periods) {
  numbersToDisplay = periods;
  resetTimer = true;
  beep();
}

isRun フラグが false から true に変化すると、期間を開始します。



// Run the period
void runPeriod() {
  if (unitTimer()) {
    numbersToDisplay--;
    if (0 >= numbersToDisplay) {
      isRun = false;
      endOfPeriodMelody();
    }
  }
}

isRun フラグが true の間は、表示する数字を 1 分ごとにカウントダウンしていきます。0 になるとメロディを演奏して終了です。



// Stop the period
void stopPeriod() {
  if (numbersToDisplay) {
    numbersToDisplay = 0;
    beep();
  }
  currPeriod++;
  if (numberOfPeriods <= currPeriod) currPeriod = 0;
}

isRun フラグが true から false に変化すると終了で、次の期間へ移行します。
numberToDisplay が 0 ではないときはストップボタンが押されたということなので、強制的に終了にします。



// LEDs control and behavior
void ledsControl() {
  static const int FORCUS = 0;
  static const int REST = 1;

  int pos = currPeriod % numberOfLedPins;
  if (isRun) {
    digitalWrite(ledPins[pos], ledBlinker() ? LED_ON : LED_OFF);
  } else {
    digitalWrite(ledPins[FORCUS], FORCUS == pos ? LED_ON : LED_OFF);
    digitalWrite(ledPins[REST], REST == pos ? LED_ON : LED_OFF);
  }
}

LED 表示のコントロールです。
期間に応じて対応する LED を点灯します。期間が進行している間は点滅します。



// LED blinker
bool ledBlinker() {
  static const int interval = 500; // mS
  static bool state = true;
  static unsigned long prev = millis();

  unsigned long curr = millis();
  if (interval <= (curr - prev)) {
    state = !state;
    prev = millis();
  }
  return state;
}

LED の点滅のコントロール。



// Turn off all LEDs
void turnOffLeds() {
  for (int i = 0; i < numberOfLedPins; i++) {
    digitalWrite(ledPins[i], LED_OFF);
  }
}

LED をすべて消灯します。



//End of period melody
void endOfPeriodMelody() {
  static const int STOP_BUTTON = 1;

  Timer1.stop();
  turnOffDigits();
  turnOffLeds();
  attachInterrupt(digitalPinToInterrupt(buttonPins[STOP_BUTTON]), stopMelody, LOW);
  toneMelody();
  detachInterrupt(digitalPinToInterrupt(buttonPins[STOP_BUTTON]));
  stopNote = false;
  Timer1.start();
}

集中期間の終了時のメロディ演奏です。

演奏中にダイナミック点灯の割込みがあると音が途切れてしまうので、割込みを止め、表示を消しています。代わりにストップボタンの割込みで演奏を中止できるようにしてあります。



// Play melody
void toneMelody() {
  for (int thisNote = 0; thisNote < numberOfMelody; thisNote++) {
    if (stopNote) break;
    int noteDuration = noteTempo / noteDurations[thisNote];
    int pauseBetweenNotes = noteDuration * notePause;
    tone(piezoPin, melody[thisNote], noteDuration);
    delay(pauseBetweenNotes);
  }
}

演奏の本体は、スケッチ例の toneMelody をそのまま利用させてもらいました。
メロディを自由に設定できるのでこうしたのですが、外部にメロディ IC を置いて演奏させる、なんてのがベターじゃないかとも思っています。



// Stop melody interrupt
void stopMelody() {
  stopNote = true;
}

メロディ演奏を中止させるボタン割込みのハンドラです。



// Beep
void beep() {
  tone(piezoPin, NOTE_A7, 50);
}

ボタン操作時のビープ音。



// Put into sleep mode
void sleepMode() {
  static const int WAKE_UP_BUTTON = 0;
  static unsigned long prev = millis();

  if (!isRun) {
    unsigned long curr = millis();
    if (sleepTime <= (curr - prev)) {
      turnOffDigits();
      attachInterrupt(digitalPinToInterrupt(buttonPins[WAKE_UP_BUTTON]), wakeUp, LOW);
      sleep_mode();
      detachInterrupt(digitalPinToInterrupt(buttonPins[WAKE_UP_BUTTON]));
      prev = millis();
    }
  } else {
    prev = millis();
  }
}

タイマーが停止して 3 分経過すると、AVR をパワーダウンモードにします。
パワーダウンモード中にスタートボタンを押すと、パワーダウンを解除して、タイマーがスタートします。

パワーダウンと言っても Arduino 自体は 10 数 mA 消費していますので、スイッチの切り忘れのないように LED は点灯したままにしています。
ちなみに Arduino NANO 本体の電源 LED は点灯しないようにしました。こいつは 3mA 程度消費しますが、動作表示用の LED は 0.9mA 流れるだけです。



// Wake up interrupt
void wakeUp() {
  beep();
}

パワーダウンモードの解除ボタンの割込みハンドラです。



void setup() {
  for (int i = 0; i < numberOfDigitPins; i++) {
    pinMode(digitPins[i], OUTPUT);
    digitalWrite(digitPins[i], DIGIT_OFF);
  }
  for (int i = 0; i < numberOfSegmentPins; i++) {
    pinMode(segmentPins[i], OUTPUT);
  }
  for (int i = 0; i < numberOfButtonPins; i++) {
    pinMode(buttonPins[i], INPUT_PULLUP);
  }
  for (int i = 0; i < numberOfLedPins; i++) {
    pinMode(ledPins[i], OUTPUT);
  }
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, LED_OFF);

  const int interruptInterval = 1000; // uS
  Timer1.initialize(interruptInterval);
  Timer1.attachInterrupt(displayInterrupt);

  set_sleep_mode(SLEEP_MODE_PWR_DOWN);
}

setup() では、各ピンの動作モードを設定しています。
D13 につながっている内蔵 LED (LED_BUILDIN) は、放置すると昼行灯のように点灯してしまうので、意図的に消灯させます。

ダイナミック点灯用のタイマー TimerOne の設定、パワーダウンモードの設定も行ないます。



void loop() {
  static bool wasRun = false;
  int periods = periodsTable[currPeriod];

  detectButtons();
  if (isRun && !wasRun) startPeriod(periods);
  if (isRun) runPeriod();
  if (!isRun && wasRun) stopPeriod();
  wasRun = isRun;

  ledsControl();
  sleepMode();
}