アフィリエイト広告
アフィリエイト広告

パタパタ表示機の制御・駆動回路とスケッチ

前回は、パタパタ表示機の製作過程を簡単にまとめました。

パタパタ表示機を作る
12 キーボード (ここ) とステッピングモータの駆動回路 (ここ) を作ったので、これを合わせて、押したキーの値を表示する「パタパタ表示機」を作ってみようと思います。 パタパタ表示機。最近で言えば、どこぞの駅のホームから、最後のパタパタ表...
meyon.gonna.jp
2022.05.26

今回は、その制御・駆動回路と Arduino のスケッチを記録しておきます。

制御・駆動回路

ブロックごとの回路図です。

12 キーボードを使った入力回路

12 キーボード入力回路

3 列 4 行のスイッチマトリクスです。
列側をプルアップし、行側を順次 LOW にすることで、押しボタンスイッチの状態を検出しています。

7 セグメント LED 表示回路

7 セグメント LED 表示回路

この部分は、パタパタ表示機の制御に関係はありません。Arduino からの出力データの確認のためにつけてあるだけなので、必要なければ外してかまいません。

7 セグメント LED の制御は、LED ドライバ IC TM1630 を利用しています。これを利用することで、I/O ピンは 3 個ですみますし、一度制御データを送ればずっと表示しつづけてくれますので、Arduino の負担も少なくなります。

ステッピングモータ駆動回路

ステッピングモータはユニポーラ駆動です。
モータに流れる電流を検出し、電流値が一定以上になったら給電を止めるチョッパ駆動になっています。モータ電圧は 12V 、電流は 0.25A としました。
駆動トランジスタは MOSFET 2SK4017 (60V 5A) 。ゲート回路はプッシュプルとしています。

Arduino の左にある Q13 は、原点位置検出用のフォトインタラプタです。ジャンク品なので仕様ははっきりしませんが、5V 回路で利用していたことだけわかっています。
発光側の順方向電圧は 1.2V ほどなので、電流は 5.6mA になっています。このとき、受光側はプルアップ抵抗 10KΩ できれいに ON-OFF してくれました。
出力は、通常時 LOW 、原点時に遮光され HIGH になります。

スケッチ

いつものように、備忘録的解説です。

  1. // Patapata Display Driver 2022.05.23 by meyon
  3. // 12-KeyScan Definition
  4. const byte Row0 = 2;
  5. const byte Row1 = 3;
  6. const byte Row2 = 4;
  7. const byte Row3 = 5;
  8. const byte Column0 = A3;
  9. const byte Column1 = A4;
  10. const byte Column2 = A5;
  12. // Stepper Definition
  13. const byte A_1 = 9;
  14. const byte A_3 = 10;
  15. const byte B_1 = 11;
  16. const byte B_3 = 12;
  17. const byte positionSensor = A2;
  19. byte sequence[] = {B0101, B0110, B1010, B1001};
  20. byte numberOfPhase = sizeof(sequence) / sizeof(sequence[0]);
  22. // 7-SD Driver TM1630 Definition
  23. #define DISPLAY_MODE 0x00
  24. #define WRITE_REG_AUTO_ADDR 0x40
  25. #define WRITE_REG_FIXED_ADDR 0x44
  26. #define READ_KEY_SCAN 0x42
  27. #define SET_DISPLAY_ADDR 0xC0
  28. #define DISPLAY_OFF 0x80
  29. #define DISPLAY_ON 0x88 | 0x84
  30. #define STB_ENABLE LOW
  31. #define STB_DISABLE HIGH
  32. #define DOT_POSITION -1
  34. const byte dioPin = 6;
  35. const byte clkPin = 7;
  36. const byte stbPin = 8;
  38. const byte numberOfDigits = DISPLAY_MODE & 1 ? 5 : 4;
  39. byte gridData[numberOfDigits] = {0};
  41. const byte digit[] = {
  42.   0b01111110, // 0
  43.   0b00001100, // 1
  44.   0b10110110, // 2
  45.   0b10011110, // 3
  46.   0b11001100, // 4
  47.   0b11011010, // 5
  48.   0b11111010, // 6
  49.   0b01001110, // 7
  50.   0b11111110, // 8
  51.   0b11011110, // 9
  52.   0b00000000, // 10:blank
  53.   0b00100000, // 11:dot
  54. };
  56. const byte blank = 10;
  57. const byte dot = 11;

I/O ピンとかコマンドとか表示データとかの定義です。
19 行目が 2-2 相励磁方式での各コイルの励磁パターン定義です。TM1630 のコマンド定義も、これまでと変更はありません。

  1. void setup() {
  2. // 12-KeyScan Setup
  3.   pinMode(Row0, OUTPUT);
  4.   pinMode(Row1, OUTPUT);
  5.   pinMode(Row2, OUTPUT);
  6.   pinMode(Row3, OUTPUT);
  7.   pinMode(Column0, INPUT);
  8.   pinMode(Column1, INPUT);
  9.   pinMode(Column2, INPUT);
  11.   digitalWrite(Row0, HIGH);
  12.   digitalWrite(Row1, HIGH);
  13.   digitalWrite(Row2, HIGH);
  14.   digitalWrite(Row3, HIGH);
  16. // Stepper Setup
  17.   pinMode(A_1, OUTPUT);
  18.   pinMode(A_3, OUTPUT);
  19.   pinMode(B_1, OUTPUT);
  20.   pinMode(B_3, OUTPUT);
  21.   pinMode(positionSensor, INPUT);
  23.   goHome();
  25. // 7-SD Driver TM1630 Setup
  26.   pinMode(dioPin, OUTPUT);
  27.   pinMode(clkPin, OUTPUT);
  28.   pinMode(stbPin, OUTPUT);
  29. }

各 I/O ピンのモード設定です。
81 行目は、起動時にパタパタ表示機を原点位置に送る制御です。

  1. // 12-Keyboard Scan
  2. unsigned int keyscan() {
  3.   unsigned int ks = 0xC000;
  5.   digitalWrite(Row0, LOW);
  6.   ks |= (!digitalRead(Column0)<<0 | !digitalRead(Column1)<<1 | !digitalRead(Column2)<<2);
  7.   digitalWrite(Row0, HIGH);
  9.   digitalWrite(Row1, LOW);
  10.   ks |= (!digitalRead(Column0)<<3 | !digitalRead(Column1)<<4 | !digitalRead(Column2)<<5);
  11.   digitalWrite(Row1, HIGH);
  13.   digitalWrite(Row2, LOW);
  14.   ks |= (!digitalRead(Column0)<<6 | !digitalRead(Column1)<<7 | !digitalRead(Column2)<<8);
  15.   digitalWrite(Row2, HIGH);
  17.   digitalWrite(Row3, LOW);
  18.   ks |= (!digitalRead(Column0)<<9 | !digitalRead(Column1)<<10 | !digitalRead(Column2)<<11);
  19.   digitalWrite(Row3, HIGH);
  21.   return ks;
  22. }

12 キーボードの状態を返す関数です。
キーの状態は 16 ビットのビット列です。上位 4 ビットは 1100 、続く 12 ビットは、各キーが押されているときに、対応したビットが 1 になります。

  1. // Setpper Feed
  2. void feed(byte s) {
  3.   static byte phase = 0;
  4.   static int period = 50;
  6.   for(byte i = 0; i < s; i++) {
  7.     digitalWrite(A_1, sequence[phase]>>3&1 ? HIGH : LOW);
  8.     digitalWrite(A_3, sequence[phase]>>2&1 ? HIGH : LOW);
  9.     digitalWrite(B_1, sequence[phase]>>1&1 ? HIGH : LOW);
  10.     digitalWrite(B_3, sequence[phase]>>0&1 ? HIGH : LOW);
  12.     phase++;
  13.     if((numberOfPhase - 1) < phase) phase = 0;
  15.     delay(period);
  16.   }
  18.   digitalWrite(A_1, LOW);
  19.   digitalWrite(A_3, LOW);
  20.   digitalWrite(B_1, LOW);
  21.   digitalWrite(B_3, LOW);
  22. }

ステッピングモータを、引数のステップ数だけ回転させる関数です。
115 行目が回転速度です。
回転中は他の操作を受け付けません。引数分ステップを送ったら、給電を切ります。

  1. // Detect Home position
  2. void goHome() {
  3.   feed(12);
  4.   while(LOW == digitalRead(positionSensor)) {
  5.     feed(1);
  6.   }
  7. }

ステッピングモータを原点位置へ送る関数です。
電源投入時は回転が不安定になるので、いったん 12 ステップ送ってから、原点センサが HIGH になるまで 1 ステップずつ送ります。

  1. // 7-Segment Display Drive
  2. void displayNumbers(int n) {
  3.   for(byte i = 0; i < numberOfDigits; i++) {
  4.     int exponentialInDecimal = pow(10, i) + 0.5;
  5.     bool zeroSuppression = (0 != i) && (DOT_POSITION < i) && (exponentialInDecimal > n);
  6.     gridData[i] = zeroSuppression ? blank : n / exponentialInDecimal % 10 ;
  7.   }
  9.   digitalWrite(stbPin, STB_ENABLE);
  10.   shiftOut(dioPin, clkPin, LSBFIRST, DISPLAY_MODE);
  11.   digitalWrite(stbPin, STB_DISABLE);
  13.   digitalWrite(stbPin, STB_ENABLE);
  14.   shiftOut(dioPin, clkPin, LSBFIRST, WRITE_REG_AUTO_ADDR);
  15.   digitalWrite(stbPin, STB_DISABLE);
  17.   digitalWrite(stbPin,STB_ENABLE);
  18.   shiftOut(dioPin, clkPin, LSBFIRST, SET_DISPLAY_ADDR | 0x00);
  19.   for(byte i = 0; i < numberOfDigits; i++) {
  20.     shiftOut(dioPin, clkPin, LSBFIRST, digit[gridData[i]]);
  21.     shiftOut(dioPin, clkPin, LSBFIRST, DOT_POSITION == i ? digit[dot] : 0);
  22.   }
  23.   digitalWrite(stbPin, STB_DISABLE);
  25.   digitalWrite(stbPin, STB_ENABLE);
  26.   shiftOut(dioPin, clkPin, LSBFIRST, DISPLAY_ON);
  27.   digitalWrite(stbPin, STB_DISABLE);
  28. }

TM1630 により 7 セグメント LED 表示器へ数値を表示させる関数です。引数に表示したい数値を渡します。
これも、これまでと変更はありません。

  1. void loop() {
  2.   static byte keyData = 1;
  3.   static byte currentKeyData = keyData;
  5.   unsigned int keyStatus = keyscan();
  7.   switch(keyStatus) {
  8.     case 0xC001: keyData = 1; break;
  9.     case 0xC002: keyData = 2; break;
  10.     case 0xC004: keyData = 3; break;
  11.     case 0xC008: keyData = 4; break;
  12.     case 0xC010: keyData = 5; break;
  13.     case 0xC020: keyData = 6; break;
  14.     case 0xC040: keyData = 7; break;
  15.     case 0xC080: keyData = 8; break;
  16.     case 0xC100: keyData = 9; break;
  17.     case 0xC200: keyData = 10; break;
  18.     case 0xC400: keyData = 11; break;
  19.     case 0xC800: keyData = 12;
  20.   }
  22.   displayNumbers(keyData);
  24.   if(keyData >= currentKeyData) {
  25.     feed(4 * (keyData - currentKeyData));
  26.     currentKeyData = keyData;
  27.   } else if(keyData < currentKeyData) {
  28.     feed(4 * (12 + keyData - currentKeyData));
  29.     currentKeyData = keyData;
  30.   }
  31. }

176〜191 行で、キーの状態のビット列に応じて、表示する数値を分岐しています。複数のキーを押した場合の規定はありませんので、無視されます。
193 行目で、7 セグメント LED に数値を表示します。

195〜201 行で、ステッピングモータを送るステップ数を算出しています。
パタパタ表示機の数値を 1 進めるとき、ステッピングモータは 4 ステップ送ります。
表示する数値が大きくなるときは、現在値との差分だけ進めます。数値が小さくなる場合、逆回転はできませんから、差分に 12 を足した数を進めることになります。

作ってみての、感想など

表示部分の構造は、もっと試行錯誤してみないといけないようです。最も気になるところは、フラップの上下の位置が揃わないこと。フラップの取り付け穴と爪の位置関係がビミョーです。

製作途中の表示部を見つけた孫 (6歳) が「パタパタ紙芝居だ！」と言っていました。よくわかったねぇ。でも、どこでそんな仕掛けを見たんでしょ？
今回使ったステッピングモータは 48 ステップですが、1-2 相励磁すると 96 ステップで回すことができます。ってことは、96 枚のパタパタ紙芝居が ……

あ、まぁ、構想だけは温めておきましょうか (；´Д｀)

タイトルとURLをコピーしました